blob: de777ddb542ba85969b3a78f7db68f32296cbe9e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
/* SPDX-License-Identifier: GPL-2.0-or-later */
/* SPDX-FileCopyrightText: 2000-2004 Wolfgang Denk <wd@denx.de>, DENX Software Engineering */
#include <asm/barebox.lds.h>
OUTPUT_FORMAT(BAREBOX_OUTPUT_FORMAT)
OUTPUT_ARCH(BAREBOX_OUTPUT_ARCH)
ENTRY(start)
SECTIONS
{
#ifdef CONFIG_RELOCATABLE
. = 0x0;
#else
. = TEXT_BASE;
#endif
.image_start : { *(.__image_start) }
#ifndef CONFIG_PBL_IMAGE
PRE_IMAGE
#endif
. = ALIGN(4);
._text : { *(._text) }
.text :
{
_stext = .;
*(.text_entry*)
__bare_init_start = .;
*(.text_bare_init*)
__bare_init_end = .;
__exceptions_start = .;
KEEP(*(.text_exceptions*))
__exceptions_stop = .;
*(.text*)
}
BAREBOX_BARE_INIT_SIZE
. = ALIGN(4);
.rodata : {
*(.rodata*)
RO_DATA_SECTION
}
_etext = .; /* End of text and rodata section */
_sdata = .;
. = ALIGN(4);
.data : { *(.data*) }
.barebox_imd : { BAREBOX_IMD }
BAREBOX_RELOCATION_TABLE
_edata = .;
.image_end : { *(.__image_end) }
. = ALIGN(4);
.__bss_start : { *(.__bss_start) }
.bss : { *(.bss*) }
.__bss_stop : { *(.__bss_stop) }
_end = .;
_barebox_image_size = __bss_start - TEXT_BASE;
}
|
