summaryrefslogtreecommitdiffstats
path: root/arch/arm/mach-omap/omap3_clock_core.S
blob: 21a1902690f2061b2df615e768f0a3e5e75246a2 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
/**
 * @file
 * @brief Provides PRCM divisors and SRAM execution code.
 *
 * FileName: arch/arm/mach-omap/omap3_clock_core.S
 *
 * This provides two things:
 * @li @ref omap3_clock.c cannot have switch or global variables.
 * This file provides the constant data for the file to use.
 *
 * @li @ref prcm_init cannot execute certain critical clock
 * configurations while running in SDRAM/Flash. This provides
 * relocation and execution capability for the same.
 *
 * Orignally from http://linux.omap.com/pub/bootloader/3430sdp/barebox-v1.tar.gz
 */
/*
 * (C) Copyright 2006-2008
 * Texas Instruments, <www.ti.com>
 * Richard Woodruff <r-woodruff2@ti.com>
 * Nishanth Menon <x0nishan@ti.com>
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License as
 * published by the Free Software Foundation; either version 2 of
 * the License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
 * MA 02111-1307 USA
 */

#include <config.h>
#include <mach/silicon.h>
#include <mach/clocks.h>
#include <mach/gpmc.h>

#ifdef CONFIG_OMAP3_COPY_CLOCK_SRAM
/**
 * @fn void cpy_clk_code(u32 R1)
 *
 * @brief cpy_clk_code: relocates clock code into SRAM where its safer to
 * execute
 *
 * @param[in] R1 = SRAM destination address.
 *
 * @return void
 */
.global cpy_clk_code
 cpy_clk_code:
        /* Copy DPLL code into SRAM */
        adr     r0, go_to_speed         /* get addr of clock setting code */
        mov     r2, #384                /* r2 size to copy (div by 32 bytes) */
        mov     r1, r1                  /* r1 <- dest address (passed in) */
        add     r2, r2, r0              /* r2 <- source end address */
next2:
        ldmia   r0!, {r3-r10}           /* copy from source address [r0]    */
        stmia   r1!, {r3-r10}           /* copy to   target address [r1]    */
        cmp     r0, r2                  /* until source end address [r2]    */
        bne     next2
	mov	pc, lr                  /* back to caller */

/**
 * @fn void go_to_speed(u32 R0, u32 R1, u32 R3)
 *
 * @brief go_to_speed: Function which configures the clocks
 *  Moves to bypass, -Commits clock dividers, -puts dpll at speed
 *               -executed from SRAM.
 * @warning Note: If core unlocks/relocks and SDRAM is running fast already
 *        it gets confused.  A reset of the controller gets it back. Taking
 *        away its L3 when its not in self refresh seems bad for it.
 *        Normally, this code runs from flash before SDR is init so that
 *        should be ok.
 *
 * @param[in] R1 = SRAM destination address.
 * @param[in] R0 = CM_CLKEN_PLL-bypass value
 * @param[in] R1 = CM_CLKSEL1_PLL-m, n, and divider values
 * @param[in] R2 = CM_CLKSEL_CORE-divider values
 * @param[in] R3 = CM_IDLEST_CKGEN - addr dpll lock wait
 *
 * @return void
 */
.global go_to_speed
 go_to_speed:
        stmfd sp!, {r4-r6}

        /* move into fast relock bypass */
        ldr     r4, pll_ctl_add
        str     r0, [r4]
wait1:
        ldr     r5, [r3]       /* get status */
        and     r5, r5, #0x1   /* isolate core status */
        cmp     r5, #0x1       /* still locked? */
        beq     wait1          /* if lock, loop */

	/* set new dpll dividers _after_ in bypass */
	ldr     r5, pll_div_add1
        str     r1, [r5]          /* set m, n, m2 */
        ldr     r5, pll_div_add2
        str     r2, [r5]          /* set l3/l4/.. dividers*/
        ldr     r5, pll_div_add3  /* wkup */
        ldr     r2, pll_div_val3  /* rsm val */
        str     r2, [r5]
        ldr     r5, pll_div_add4  /* gfx */
        ldr     r2, pll_div_val4
        str     r2, [r5]
        ldr     r5, pll_div_add5  /* emu */
        ldr     r2, pll_div_val5
        str     r2, [r5]

#if 0
        /* FIXME: now prepare GPMC (flash) for new dpll speed
	 * For NOR/NAND/OneNAND boot ->make this as Kconfig?
	 */
	/* flash needs to be stable when we jump back to it */
        ldr     r6, flash_cfg_offset
        ldr     r5, flash_cfg_addr /* CFG1 */
        ldr     r2, flash_cfg1_val
        str     r2, [r5]
        add	r5, r5, r6 /* CFG2 */
        ldr     r2, flash_cfg2_val
        str     r2, [r5]
        add	r5, r5, r6 /* CFG3 */
        ldr     r2, flash_cfg3_val
        str     r2, [r5]
        add	r5, r5, r6 /* CFG4 */
        ldr     r2, flash_cfg4_val
        str     r2, [r5]
        add	r5, r5, r6 /* CFG5 */
        ldr     r2, flash_cfg5_val
        str     r2, [r5]
        add	r5, r5, r6 /* CFG6 */
        ldr     r2, flash_cfg6_val
        str     r2, [r5]
#endif /* Debug */

        /* lock DPLL3 and wait a bit */
        orr     r0, r0, #0x7   /* set up for lock mode */
        str     r0, [r4]       /* lock */
        nop                    /* ARM slow at this point working at sys_clk */
        nop
        nop
        nop
wait2:
        ldr     r5, [r3]       /* get status */
        and     r5, r5, #0x1   /* isolate core status */
        cmp     r5, #0x1       /* still locked? */
        bne     wait2          /* if lock, loop */
        nop
        nop
        nop
        nop
        ldmfd sp!, {r4-r6}
        mov     pc, lr           /* back to caller, locked */

_go_to_speed: .word go_to_speed

/* these constants need to be close for PIC code */
/* FIXME: The Nor has to be in the Flash Base CS0 for this condition to happen*/
#if 0
flash_cfg_addr:
    .word GPMC_REG(CONFIG1_0)
flash_cfg_offset:
    .word GPMC_REG(CONFIG2_0) - GPMC_REG(CONFIG1_0)
flash_cfg1_val:
    .word  CONFIG_VALUE_GPMC_CONFIG1
flash_cfg2_val:
    .word  CONFIG_VALUE_GPMC_CONFIG2
flash_cfg3_val:
    .word  CONFIG_VALUE_GPMC_CONFIG3
flash_cfg4_val:
    .word  CONFIG_VALUE_GPMC_CONFIG4
flash_cfg5_val:
    .word  CONFIG_VALUE_GPMC_CONFIG5
flash_cfg6_val:
    .word  CONFIG_VALUE_GPMC_CONFIG6
#endif
pll_ctl_add:
    .word CM_CLKEN_PLL
pll_div_add1:
    .word CM_CLKSEL1_PLL
pll_div_add2:
    .word CM_CLKSEL_CORE
pll_div_add3:
    .word CM_CLKSEL_WKUP
pll_div_val3:
    .word (WKUP_RSM << 1)
pll_div_add4:
    .word CM_CLKSEL_GFX
pll_div_val4:
    .word (GFX_DIV << 0)
pll_div_add5:
    .word CM_CLKSEL1_EMU
pll_div_val5:
    .word CLSEL1_EMU_VAL

#endif /* OMAP3_CLOCK_COPY_SRAM */

	/* the literal pools origin */
	.ltorg

/* DPLL(1-4) PARAM TABLES */
/* Each of the tables has M, N, FREQSEL, M2 values defined for nominal
 * OPP (1.2V). The fields are defined according to dpll_param
 * struct(omap3_clock.c). MAX index is as per omap3_clock.h
 */

mpu_dpll_param:
/* 12MHz */
/* ES2 */
.word 0x0FA,0x05,0x07,0x01

/* 13MHz */
/* ES2 */
.word 0x1F4,0x0C,0x03,0x01

/* 19.2MHz */
/* ES2 */
.word 0x271,0x17,0x03,0x01

/* 26MHz */
/* ES2 */
.word 0x0FA,0x0C,0x07,0x01

/* 38.4MHz */
/* ES2 */
.word 0x271,0x2F,0x03,0x01

.globl get_mpu_dpll_param
get_mpu_dpll_param:
	adr r0, mpu_dpll_param
	mov pc, lr

iva_dpll_param:
/* 12MHz */
/* ES2 */
.word 0x0B4,0x05,0x07,0x01

/* 13MHz */
/* ES2 */
.word 0x168,0x0C,0x03,0x01

/* 19.2MHz */
/* ES2 */
.word 0x0E1,0x0B,0x06,0x01

/* 26MHz */
/* ES2 */
.word 0x0B4,0x0C,0x07,0x01

/* 38.4MHz */
/* ES2 */
.word 0x0E1,0x17,0x06,0x01

.globl get_iva_dpll_param
get_iva_dpll_param:
	adr r0, iva_dpll_param
	mov pc, lr

core_dpll_param:
/* 12MHz */
/* ES2 */
.word 0x0A6,0x05,0x07,0x01

/* 13MHz */
/* ES2 */
.word 0x14C,0x0C,0x03,0x01

/* 19.2MHz */
/* ES2 */
.word 0x19F,0x17,0x03,0x01

/* 26MHz */
/* ES2 */
.word 0x0A6,0x0C,0x07,0x01

/* 38.4MHz */
/* ES2 */
.word 0x19F,0x2F,0x03,0x01

.globl get_core_dpll_param
get_core_dpll_param:
	adr r0, core_dpll_param
	mov pc, lr

/* PER DPLL values are same for both ES1 and ES2 */
per_dpll_param:
/* 12MHz */
.word 0xD8,0x05,0x07,0x09

/* 13MHz */
.word 0x1B0,0x0C,0x03,0x09

/* 19.2MHz */
.word 0xE1,0x09,0x07,0x09

/* 26MHz */
.word 0xD8,0x0C,0x07,0x09

/* 38.4MHz */
.word 0xE1,0x13,0x07,0x09

.globl get_per_dpll_param
get_per_dpll_param:
	adr r0, per_dpll_param
	mov pc, lr