summaryrefslogtreecommitdiffstats
path: root/arch/mips/lib/barebox.lds.S
blob: 86a469a0422647098871afb7fad3be9a102e37e7 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
/* SPDX-License-Identifier: GPL-2.0-only */
/*
 * Copyright (C) 2011 Antony Pavlov <antonynpavlov@gmail.com>
 */


#include <asm-generic/barebox.lds.h>

OUTPUT_ARCH(mips)
ENTRY(_start)
SECTIONS
{
	. = TEXT_BASE;

	. = ALIGN(4);

	.image_start : { *(.__image_start) }
	.text      :
	{
		_stext = .;
		_text = .;
		*(.text_entry*)
		__bare_init_start = .;
		*(.text_bare_init*)
		__bare_init_end = .;
		*(.text*)
	}
	BAREBOX_BARE_INIT_SIZE

	PRE_IMAGE

	. = ALIGN(4);
	.rodata : { *(.rodata*) }

	_etext = .;			/* End of text and rodata section */
	_sdata = .;

	. = ALIGN(4);
	.data : { *(.data*) }

	.barebox_imd : { BAREBOX_IMD }

	. = .;
	.barebox_cmd : { BAREBOX_CMDS }
	.barebox_ratp_cmd : { BAREBOX_RATP_CMDS }
	.barebox_magicvar : { BAREBOX_MAGICVARS }
	.barebox_initcalls : { BAREBOX_INITCALLS }
	.barebox_exitcalls : { BAREBOX_EXITCALLS }
	__usymtab : { BAREBOX_SYMS }

#ifdef CONFIG_PCI
	__start_pci_fixups_early = .;
	.pci_fixup_early : { KEEP(*(.pci_fixup_early)) }
	__end_pci_fixups_early = .;
	__start_pci_fixups_header = .;
	.pci_fixup_header : { KEEP(*(.pci_fixup_header)) }
	__end_pci_fixups_header = .;
	__start_pci_fixups_enable = .;
	.pci_fixup_enable : { KEEP(*(.pci_fixup_enable)) }
	__end_pci_fixups_enable = .;
#endif
	.oftables : { BAREBOX_CLK_TABLE }

	.dtb : { BAREBOX_DTB }

	_edata = .;
	.image_end : { *(.__image_end) }

	. = ALIGN(4);
	/*
	 * .rel must come last so that the mips-relocs tool can shrink
	 * the section size & the PT_LOAD program header filesz.
	 */
	.data.reloc : {
		__rel_start = .;
		BYTE(0x0)
		. += (32 * 1024) - 1;
	}

	_end = .;

	.bss __rel_start (OVERLAY) : {
		__bss_start = .;
		*(.sbss.*)
		*(.bss.*)
		*(COMMON)
		. = ALIGN(4);
		__bss_stop = .;
	}

}